
    Stampede

Load testing for Elixir and Phoenix, with built-in Phoenix Channels and LiveView support.
Generic load testing tools see a Phoenix channel as a plain WebSocket, so each
test has to rebuild the protocol by hand: join messages, refs, replies and
heartbeats. LiveView is harder still, since every session starts with a page
load that hands out the tokens the socket needs. Stampede speaks both
natively, along with plain HTTP.
Every virtual user (VU) is a BEAM process and scenarios are plain Elixir
modules, so one machine can hold thousands of connections, several machines
can share one test over Erlang distribution, and your load tests can reuse
your own code.
Stampede is new and its API may still change before 1.0.

Installation
def deps do
  [
    {:stampede, "~> 0.2", only: :dev}
  ]
end
Stampede requires Elixir 1.19 or later.
A first load test
Create loadtest/lobby.exs:
defmodule MyApp.Load.Lobby do
  use Stampede.Scenario

  @impl true
  def options do
    [
      stages: [{[second: 30], 500}, {[minute: 1], 500}, {[second: 10], 0}],
      thresholds: [{"channel.join", p95: 250}, {"iteration.errors", count: 0}]
    ]
  end

  @impl true
  def run(vu) do
    {:ok, socket} = Stampede.Channels.connect("ws://localhost:4000/socket")
    {:ok, _reply} = Stampede.Channels.join(socket, "room:lobby")

    for _ <- 1..10 do
      {:ok, _reply} = Stampede.Channels.push(socket, "room:lobby", "new_msg", %{body: "hi from #{vu.id}"})
      Process.sleep(1_000)
    end
  end
end
And run it:
$ mix stampede.run loadtest/lobby.exs

Stampede ramps up to 500 VUs over 30 seconds, holds them for a minute and
ramps down, printing progress every second. Each VU calls run/1 over and
over. At the end it prints a summary like this one, from a run with 6,000 VUs
spread over three nodes, against a Phoenix app on the same laptop:
Demo.Chat ran for 15.0s

  metric          count   rate/s     mean     p50      p90      p95      p99       max
  channel.join     6000   399.89  10.72ms  5.49ms  18.59ms  31.90ms  97.77ms  103.81ms
  channel.push   139348  9287.39   2.56ms   854µs   6.84ms  11.27ms  22.25ms   55.84ms
  ws.connect       6000   399.89  16.28ms 11.50ms  28.29ms  35.25ms 134.64ms  209.06ms

  thresholds
    pass  channel.join p95 <= 500.00ms (31.90ms)
    pass  iteration.errors count <= 0 (0)
The task exits with status 1 when a threshold fails, so it can run in CI.
Scenarios
A scenario implements Stampede.Scenario:
	run/1 runs one iteration of a VU. It gets a Stampede.VU with the VU's
id, its iteration count and the data returned by setup/1.
	options/0 returns the default options of the run, optional.
	setup/1 runs once before the first VU starts, optional. Use it to create
accounts or sign tokens that every VU needs.

If an iteration raises, the error is counted under iteration.errors, shown
in the summary, and the VU moves on to its next iteration. Sockets opened
during an iteration are closed when it ends.
VUs or a rate
A run either keeps a number of VUs busy, or starts iterations at a rate.
stages are {duration, target} tuples, each moving the number of VUs in a
straight line from the previous target to its own. vus: 100, duration: [minute: 1] holds 100 VUs for a minute. Durations are milliseconds or
anything Kernel.to_timeout/1 accepts, such as [second: 30].
A VU only starts its next iteration once the last one is done, so when the
server slows down, the load eases off too. Real users don't wait for each
other, which is why rate starts iterations at a fixed pace instead, however
long they take:
[rate: 200, duration: [minute: 5], max_vus: 1_000]
[rate_stages: [{[minute: 1], 500}, {[minute: 5], 500}]]
VUs are started as needed and reused between iterations, keeping their
connections. max_vus caps how many iterations may be in progress, and the
ones that cannot start are counted as iterations.dropped.
From the command line, --vus 100 or --rate 200 with --duration 1m
replace a scenario's own settings.
Checks and thresholds
Checks are assertions that do not end the iteration when they fail:
{:ok, response} = Stampede.HTTP.get("http://localhost:4000/api/posts")
Stampede.check("status is 200", response.status == 200)
Thresholds are the highest value a statistic may reach for the run to pass:
thresholds: [
  {"channel.join", p95: 250, max: 2_000},
  {"status is 200", failed_rate: 0.01},
  {"iteration.errors", count: 0}
]
Timings have min, mean, p50, p90, p95, p99 and max, in
milliseconds. Checks have failed and failed_rate. Every metric has
count and rate, per second. Percentiles are within 1% of the exact value,
however many samples a run collects.
Metrics
Stampede records iteration, iteration.errors, iterations.dropped and
vu.crashes for every scenario, and the clients below record their own.
Record your own with Stampede.measure/2, Stampede.record/3,
Stampede.increment/2 and Stampede.check/2:
Stampede.measure("broadcast.roundtrip", fn ->
  :ok = Stampede.Channels.cast(socket, "room:lobby", "shout", %{from: vu.id})
  {:ok, _payload} = Stampede.Channels.await(socket, "room:lobby", "shout", match: &(&1["from"] == vu.id))
end)
HTTP
Stampede.HTTP sends requests and records them as http.request, counting
transport errors and statuses of 400 or more as http.request.errors:
{:ok, %{status: 200, body: body}} = Stampede.HTTP.get("http://localhost:4000/api/posts")
{:ok, %{status: 201}} = Stampede.HTTP.post("http://localhost:4000/api/posts", json: %{title: "Hi"})
Each VU keeps its connections open between requests, as browsers do, and
reconnects when the server closed one. Against a Phoenix app on the same
laptop, 2,000 GET requests per second for 10 seconds held their rate with a
p99 of 1.56ms.
Phoenix Channels
Stampede.Channels covers what a JavaScript client does:
	connect/2 with params, headers and either serializer ("2.0.0" or "1.0.0")
	join/4, push/5 and leave/3, which wait for the reply
	cast/4 for events the channel does not reply to
	await/4 for pushes and broadcasts from the server, with an optional
:match function to pick one out of many
	heartbeats, sent every 30 seconds by default

It records ws.connect, ws.disconnects, channel.join, channel.push,
channel.leave and channel.messages, plus an .errors counter for each
request type. A push to a channel that crashes fails with
{:error, :channel_crashed} instead of a timeout.
LiveView
Stampede.LiveView loads a page the way a browser does, then joins the
LiveView it renders, with the page's CSRF token and cookies:
@impl true
def run(_vu) do
  {:ok, view} = Stampede.LiveView.connect("http://localhost:4000/posts/new")
  {:ok, _reply} = Stampede.LiveView.change(view, "validate", %{"post" => %{"title" => "Hi"}})
  {:ok, _reply} = Stampede.LiveView.submit(view, "save", %{"post" => %{"title" => "Hi there"}})
  {:ok, _reply} = Stampede.LiveView.click(view, "like", %{"id" => "1"})
  {:ok, _view} = Stampede.LiveView.navigate(view, "/posts")
end
click/4, change/4 and submit/4 send what phx-click, phx-change and
phx-submit would, and return what handle_event/3 replied, if anything.
Pass target: 1 to send an event to a component, like phx-target does.
await/2 waits for updates the LiveView sends on its own.
patch/3 and navigate/3 move between pages like <.link patch> and
<.link navigate> do, over the same socket when LiveView allows it. When an
event makes the LiveView navigate on its own, it returns
{:error, {:live_redirect, %{"to" => to}}} as Phoenix.LiveViewTest does,
and navigate/3 follows it.
connect/2 follows redirects and keeps the cookies they set, so a route that
signs a test user in and redirects to the page under test is enough to load
test pages behind a login. A run records live.page, live.join,
live.event, live.patch and live.navigate.
Results
Stampede.run/2 returns a Stampede.Result, with every metric's summary and
a timeline of what happened during each second of the run, to see when
latency went up during a ramp. --out results.json writes it all as JSON,
and so does Stampede.Reporter.to_json/1.
Stampede also emits :telemetry events for every timing, counter and check,
and for every second of a run, to send them to your own metrics system while
a test runs. They are listed in the Stampede docs.
Spreading the load
One machine runs out of CPU or ports long before a large Phoenix app runs out
of room. Start a node on more machines, from the same project, and give them
to the task:
$ iex --sname worker --cookie load -S mix
$ elixir --sname loader --cookie load -S mix stampede.run loadtest/lobby.exs --nodes worker@host

VUs and rates are split evenly between the nodes, and their metrics are
merged as if they ran on one. From code, pass nodes: [node() | Node.list()].
Running from code
Load tests can also run from a script, without a Mix project:
Mix.install([{:stampede, "~> 0.2"}])

defmodule Lobby do
  use Stampede.Scenario

  @impl true
  def run(_vu) do
    {:ok, socket} = Stampede.Channels.connect("ws://localhost:4000/socket")
    {:ok, _reply} = Stampede.Channels.join(socket, "room:lobby")
    Process.sleep(1_000)
  end
end

result = Stampede.run(Lobby, vus: 100, duration: [minute: 1], progress: true)
IO.puts(Stampede.Reporter.format(result))
System.halt(if result.passed?, do: 0, else: 1)
Roadmap
	LiveView uploads
	A live dashboard
	Plain WebSocket and TCP clients

License
Copyright 2026 Mandar Joshi
Licensed under the Apache License, Version 2.0, found in the LICENSE file.


  

    Changelog

v0.2.0 (2026-10-20)
	Start iterations at a rate with :rate, :rate_stages and :max_vus,
reusing idle VUs and counting the iterations that cannot start as
"iterations.dropped"
	Spread a run over several nodes with :nodes, or --nodes from the
command line, loading the scenario on the nodes that miss it
	Stampede.HTTP, a client that keeps each VU's connections open between
requests and records "http.request"
	Checks, with Stampede.check/2 and the :failed and :failed_rate
thresholds
	A timeline of every second of the run in Stampede.Result
	Stampede.Reporter.to_json/1 and mix stampede.run --out
	Telemetry events for runs, timings, counters and checks
	A :match option for Stampede.Channels.await/4 and
Stampede.LiveView.await/2
	mix stampede.run --rate and --max-vus

Changes
	LiveView page loads reuse their connection, as browsers do. A server
holds an idle connection per user as a result, so numbers can differ from
the ones measured with 0.1.
	Runs no longer leave monitor messages in the caller's mailbox.

v0.1.0 (2026-10-20)
First release.
	Scenarios with stages, setup data and thresholds
	Timings with percentiles accurate to 1%, and counters
	A Phoenix Channels client with heartbeats, replies, broadcasts and both serializers
	A LiveView client that loads the page, following redirects, joins with its
tokens and cookies, sends clicks, form changes and submits to the LiveView
or one of its components, and patches and navigates between LiveViews
	mix stampede.run, which exits with status 1 when a threshold fails



  

    
Stampede 
    



      
Load testing for Elixir and Phoenix applications.
A load test is a module that implements Stampede.Scenario. Stampede starts
virtual users (VUs), each one a process that calls the scenario's
Stampede.Scenario.run/1 over and over, moves the number of running VUs
through the stages you configured, and records how long things take.
defmodule MyApp.Load.Lobby do
  use Stampede.Scenario

  @impl true
  def options do
    [
      stages: [{[second: 30], 1_000}, {[minute: 1], 1_000}, {[second: 10], 0}],
      thresholds: [{"channel.join", p95: 250}, {"iteration.errors", count: 0}]
    ]
  end

  @impl true
  def run(_vu) do
    {:ok, socket} = Stampede.Channels.connect("ws://localhost:4000/socket")
    {:ok, _reply} = Stampede.Channels.join(socket, "room:lobby")
    {:ok, _reply} = Stampede.Channels.push(socket, "room:lobby", "ping")
    Process.sleep(1_000)
  end
end
Run it with mix stampede.run, or from code:
result = Stampede.run(MyApp.Load.Lobby)
IO.puts(Stampede.Reporter.format(result))
Metrics
Every metric has a name and is a timing, a counter or a check. Stampede
records these on its own:
	"iteration" - how long each successful Stampede.Scenario.run/1 took
	"iteration.errors" - iterations that raised, threw or exited
	"iterations.dropped" - iterations a :rate run could not start
because all of its :max_vus were busy
	"vu.crashes" - VUs that crashed and had to be replaced
	the request metrics listed in Stampede.HTTP
	the connection and channel metrics listed in Stampede.Channels
	the page, join and event metrics listed in Stampede.LiveView

Record your own with measure/2, record/3, increment/2 and check/2.
Timings, counters and checks share one set of names.
Timings are counted in buckets that grow by 2% each, so every percentile
in a Stampede.Result is within 1% of the exact value, however many samples
the run collected.
Telemetry
Stampede emits these :telemetry events:
	[:stampede, :run, :start] - with the :system_time as measurement,
and the :scenario and its :options as metadata
	[:stampede, :run, :interval] - every second, with the number of busy
:vus as measurement, and the :scenario and the :interval, a point
of Stampede.Result's timeline, as metadata
	[:stampede, :run, :stop] - with the :duration as measurement, and
the :scenario and its :result as metadata
	[:stampede, :timing] - for every timing recorded, with its
:duration as measurement and its :name as metadata
	[:stampede, :counter] - for every counter incremented, with the
:count added as measurement and its :name as metadata
	[:stampede, :check] - for every check, with a :count of 1 as
measurement, and its :name and whether it :passed? as metadata

Durations are in native time units, as usual for telemetry. The run events
are emitted where run/2 was called, the others on the node that recorded
them.

    Functions
  


    
      
        check(name, condition)

      


        Records whether condition holds as the check name, and returns it as a
boolean.



    


    
      
        increment(name, amount \\ 1)

      


        Adds amount to the counter name.



    


    
      
        measure(name, fun)

      


        Calls fun and records how long it took as the timing name.



    


    
      
        record(name, duration, unit \\ :millisecond)

      


        Records duration, given in unit, as the timing name.



    


    
      
        run(scenario, opts \\ [])

      


        Runs scenario and returns a Stampede.Result.



    





      


      
        Functions


        


  
    
      
    
    
      check(name, condition)



        
          
        

    

  


  

      

          @spec check(String.t(), as_boolean(term())) :: boolean()


      


Records whether condition holds as the check name, and returns it as a
boolean.
Unlike a failed match, a failed check does not end the iteration. The
summary shows how often each check passed, and thresholds can limit how
many fail:
Stampede.check("status is 200", response.status == 200)

thresholds: [{"status is 200", failed_rate: 0.01}]

  



    

  
    
      
    
    
      increment(name, amount \\ 1)



        
          
        

    

  


  

      

          @spec increment(String.t(), pos_integer()) :: :ok


      


Adds amount to the counter name.

  



  
    
      
    
    
      measure(name, fun)



        
          
        

    

  


  

      

          @spec measure(String.t(), (-> result)) :: result when result: var


      


Calls fun and records how long it took as the timing name.
Returns what fun returns. Nothing is recorded if fun raises, or when it
is called outside of a run.
Stampede.measure("checkout", fn -> MyApp.Client.checkout(cart) end)

  



    

  
    
      
    
    
      record(name, duration, unit \\ :millisecond)



        
          
        

    

  


  

      

          @spec record(String.t(), non_neg_integer(), System.time_unit()) :: :ok


      


Records duration, given in unit, as the timing name.
Useful when the duration comes from somewhere else, such as a timestamp
sent back by the server.

  



    

  
    
      
    
    
      run(scenario, opts \\ [])



        
          
        

    

  


  

      

          @spec run(module(), keyword()) :: Stampede.Result.t()


      


Runs scenario and returns a Stampede.Result.
Options given here take precedence over the ones returned by the
scenario's Stampede.Scenario.options/0.
Options
	:stages - a list of {duration, target} tuples. Each stage moves the
number of running VUs in a straight line from the previous target,
starting at zero, to target over duration. A stage with no duration
jumps to its target right away.

	:vus and :duration - run a constant number of VUs, 1 by default,
for duration instead of going through stages. vus: 100, duration: [minute: 1] is the same as stages: [{0, 100}, {[minute: 1], 100}].

	:rate and :duration - start rate iterations per second for
duration, however long they take, instead of keeping a number of VUs
busy. Unlike VUs that wait for their last iteration to finish, a rate
keeps the pressure on a server that slows down, which is how real
traffic behaves. Rates can be fractions, such as 0.5.

	:rate_stages - like :stages, but each target is a rate.

	:max_vus - how many iterations a :rate run may have in progress at
once. VUs are started as needed and reused once they finish an
iteration. When all of them are busy, iterations are dropped and counted
as "iterations.dropped". Defaults to 1_000.

	:thresholds - a list of {metric, limits} tuples, such as
{"channel.join", p95: 250, max: 1_000}. Each limit is the highest
value the statistic may have for the run to pass. Timings have :min,
:mean, :p50, :p90, :p95, :p99 and :max, in milliseconds.
Checks have :failed and :failed_rate, from 0 to 1. Every metric has
:count and :rate, per second. Thresholds on a timing with no samples
fail, while counters and checks with no samples are zero.

	:nodes - the nodes to run the VUs on, [node()] by default. VUs and
rates are split evenly between them, and their metrics are merged.
Every node must be connected and able to run Stampede and the
scenario's code, for example because it was started from the same
project. A scenario compiled to a .beam file is loaded on the nodes
that miss it.

	:progress - prints the number of VUs, iterations and errors every
second. Defaults to false.


Durations are milliseconds or anything else Kernel.to_timeout/1 accepts,
such as [second: 30] or Duration.new!(minute: 1).

  


        

      


  

    
Stampede.Scenario behaviour
    



      
The behaviour of a load test.
Only run/1 is required:
defmodule MyApp.Load.Home do
  use Stampede.Scenario

  @impl true
  def options, do: [vus: 10, duration: [minute: 1]]

  @impl true
  def run(_vu) do
    {:ok, socket} = Stampede.Channels.connect("ws://localhost:4000/socket")
    {:ok, _reply} = Stampede.Channels.join(socket, "home")
    Process.sleep(500)
  end
end
use Stampede.Scenario declares the behaviour and nothing else.

    Callbacks
  


    
      
        options()

      


        Returns the default options of the scenario. See Stampede.run/2.



    


    
      
        run(vu)

      


        Runs one iteration of a VU.



    


    
      
        setup opts

      


        Runs once before the first VU starts, in the process that called
Stampede.run/2.



    





      


      
        Callbacks


        


  
    
      
    
    
      options()


        (optional)


        
          
        

    

  


  

      

          @callback options() :: keyword()


      


Returns the default options of the scenario. See Stampede.run/2.

  



  
    
      
    
    
      run(vu)



        
          
        

    

  


  

      

          @callback run(vu :: Stampede.VU.t()) :: term()


      


Runs one iteration of a VU.
Stampede calls it again as soon as it returns, until the VU is stopped.
Sockets opened with Stampede.Channels.connect/2 during an iteration are
closed when it returns, so a VU that should stay connected for the whole
test must keep run/1 from returning, for example with a loop.
If run/1 raises, throws or exits, the error is counted under
"iteration.errors" and the VU waits 100ms before its next iteration, so a
failing scenario does not spin.

  



  
    
      
    
    
      setup opts


        (optional)


        
          
        

    

  


  

      

          @callback setup(opts :: keyword()) :: term()


      


Runs once before the first VU starts, in the process that called
Stampede.run/2.
It receives the options of the run, and what it returns is given to every
VU as vu.data. Use it for work that should not be repeated, such as
creating accounts or signing tokens.

  


        

      


  

    
Stampede.VU 
    



      
A virtual user, given to Stampede.Scenario.run/1.
	:id - a number from 1 upwards, unique within the run
	:iteration - how many iterations the VU ran before this one
	:data - what Stampede.Scenario.setup/1 returned, or nil

        t()

          @type t() :: %Stampede.VU{
  data: term(),
  id: pos_integer(),
  iteration: non_neg_integer()
}


      



  


        

      


  

    
Stampede.Channels 
    



      
A Phoenix Channels client for load tests.
{:ok, socket} = Stampede.Channels.connect("ws://localhost:4000/socket", params: %{token: token})
{:ok, _reply} = Stampede.Channels.join(socket, "room:lobby")
{:ok, _reply} = Stampede.Channels.push(socket, "room:lobby", "new_msg", %{body: "hi"})
{:ok, payload} = Stampede.Channels.await(socket, "room:lobby", "new_msg")
Each socket is a process linked to the caller. It sends heartbeats, matches
every reply to the request it answers, and keeps the last 1,000 messages
pushed or broadcast by the server until they are read with await/4.
Metrics
Inside a run, sockets record:
	"ws.connect" and "ws.connect.errors"
	"ws.disconnects" - connections closed by the server or the network
	"channel.join" and "channel.join.errors"
	"channel.push" and "channel.push.errors"
	"channel.leave" and "channel.leave.errors"
	"channel.messages" - messages pushed or broadcast by the server
	"channel.messages.dropped" - messages dropped because the socket
already held 1,000 unread ones

Error replies, timeouts and closed connections all count as errors.

    Types
  


    
      
        socket()

      


    





  
    Functions
  


    
      
        await(socket, topic, event, timeout_or_opts \\ [])

      


        Waits until the server pushes or broadcasts event on topic, and returns
its payload.



    


    
      
        cast(socket, topic, event, payload \\ %{})

      


        Pushes event with payload to topic without waiting for a reply.



    


    
      
        close(socket)

      


        Closes the connection and waits for the socket to stop.



    


    
      
        connect(url, opts \\ [])

      


        Connects to the Phoenix socket at url.



    


    
      
        join(socket, topic, payload \\ %{}, opts \\ [])

      


        Joins topic, sending payload to the channel's join/3 callback.



    


    
      
        leave(socket, topic, opts \\ [])

      


        Leaves topic.



    


    
      
        push(socket, topic, event, payload \\ %{}, opts \\ [])

      


        Pushes event with payload to topic and waits for the reply.

      socket()



        
          
        

    

  


  

      

          @type socket() :: pid()


      



  


        

      

      
        Functions


        


    

  
    
      
    
    
      await(socket, topic, event, timeout_or_opts \\ [])



        
          
        

    

  


  

      

          @spec await(socket(), String.t(), String.t(), timeout() | keyword()) ::
  {:ok, term()} | {:error, term()}


      


Waits until the server pushes or broadcasts event on topic, and returns
its payload.
Messages that arrived before the call are looked at first, oldest first.
Returns {:error, :timeout} if no such message arrives in time.
The last argument is a timeout in milliseconds, or a list of options:
	:timeout - how long to wait, in milliseconds. Defaults to 5_000.

	:match - a function that gets each payload and returns whether it is
the one to wait for. Useful when other VUs broadcast the same event:
Stampede.Channels.await(socket, "room:lobby", "shout", match: &(&1["from"] == vu.id))



  



    

  
    
      
    
    
      cast(socket, topic, event, payload \\ %{})



        
          
        

    

  


  

      

          @spec cast(socket(), String.t(), String.t(), map()) :: :ok


      


Pushes event with payload to topic without waiting for a reply.

  



  
    
      
    
    
      close(socket)



        
          
        

    

  


  

      

          @spec close(socket()) :: :ok


      


Closes the connection and waits for the socket to stop.

  



    

  
    
      
    
    
      connect(url, opts \\ [])



        
          
        

    

  


  

      

          @spec connect(String.t(), keyword()) :: {:ok, socket()} | {:error, term()}


      


Connects to the Phoenix socket at url.
url is the socket's endpoint as given to the JavaScript client, such as
"ws://localhost:4000/socket". /websocket is added to its path unless it
is already there.
Options
	:params - query parameters sent with the connection, often used for
authentication
	:headers - extra headers for the upgrade request
	:vsn - the serializer version, "2.0.0" (the default) or "1.0.0".
A vsn query parameter in url takes precedence.
	:connect_timeout - how long to wait for the connection, in
milliseconds. Defaults to 10_000.
	:heartbeat_interval - how often to send a heartbeat, in milliseconds,
or nil to never send one. Defaults to 30_000, like the JavaScript
client. The connection is closed when a heartbeat is still unanswered
by the time the next one is due.
	:transport_opts - options for :gen_tcp or :ssl, given to
Mint.HTTP.connect/4

Returns {:error, reason} when the connection fails, such as a
Mint.TransportError when nothing is listening, or a
Mint.WebSocket.UpgradeFailureError when the socket's connect/3
refuses it.

  



    

    

  
    
      
    
    
      join(socket, topic, payload \\ %{}, opts \\ [])



        
          
        

    

  


  

      

          @spec join(socket(), String.t(), map(), keyword()) :: {:ok, term()} | {:error, term()}


      


Joins topic, sending payload to the channel's join/3 callback.
Returns {:ok, response} when the channel accepts the join and
{:error, response} when it refuses it. It may also return
{:error, :timeout}, or {:error, {:closed, reason}} when the connection
closes first.
Options
	:timeout - how long to wait for the reply, in milliseconds. Defaults
to 5_000.
	:metric - the timing to record the join as, or nil to record
nothing. Defaults to "channel.join".


  



    

  
    
      
    
    
      leave(socket, topic, opts \\ [])



        
          
        

    

  


  

      

          @spec leave(socket(), String.t(), keyword()) :: :ok | {:error, term()}


      


Leaves topic.
Takes the same options as join/4, with :metric defaulting to
"channel.leave".

  



    

    

  
    
      
    
    
      push(socket, topic, event, payload \\ %{}, opts \\ [])



        
          
        

    

  


  

      

          @spec push(socket(), String.t(), String.t(), map(), keyword()) ::
  {:ok, term()} | {:error, term()}


      


Pushes event with payload to topic and waits for the reply.
Returns {:ok, response} or {:error, response}, depending on what the
channel's handle_in/3 replied. Use cast/4 for events the channel does
not reply to.
Takes the same options as join/4, with :metric defaulting to
"channel.push".

  


        

      


  

    
Stampede.HTTP 
    



      
An HTTP client for load tests.
{:ok, %{status: 200, body: body}} = Stampede.HTTP.get("http://localhost:4000/api/posts")
{:ok, %{status: 201}} = Stampede.HTTP.post("http://localhost:4000/api/posts", json: %{title: "Hi"})
Responses are maps with the :status, the :headers, with lowercase
names, and the :body.
Each VU keeps a connection open to every server it talks to and sends its
next request on it, as a browser does. When the server closed it in the
meantime, a new one is opened, and a request that is safe to repeat (GET,
HEAD, PUT, DELETE or OPTIONS) is sent again on it.
Metrics
Inside a run, requests record:
	"http.request" - how long each response took, whatever its status
	"http.request.errors" - requests that failed, or whose response had a
status of 400 or more


      


      
        Summary


  
    Types
  


    
      
        response()

      


    





  
    Functions
  


    
      
        delete(url, opts \\ [])

      


        Sends a DELETE request. See request/3.



    


    
      
        get(url, opts \\ [])

      


        Sends a GET request. See request/3.



    


    
      
        patch(url, opts \\ [])

      


        Sends a PATCH request. See request/3.



    


    
      
        post(url, opts \\ [])

      


        Sends a POST request. See request/3.



    


    
      
        put(url, opts \\ [])

      


        Sends a PUT request. See request/3.



    


    
      
        request(method, url, opts \\ [])

      


        Sends a method request to url and waits for the whole response.



    





      


      
        Types


        


  
    
      
    
    
      response()



        
          
        

    

  


  

      

          @type response() :: %{
  status: non_neg_integer(),
  headers: [{String.t(), String.t()}],
  body: binary()
}


      



  


        

      

      
        Functions


        


    

  
    
      
    
    
      delete(url, opts \\ [])



        
          
        

    

  


  

      

          @spec delete(String.t(), keyword()) :: {:ok, response()} | {:error, term()}


      


Sends a DELETE request. See request/3.

  



    

  
    
      
    
    
      get(url, opts \\ [])



        
          
        

    

  


  

      

          @spec get(String.t(), keyword()) :: {:ok, response()} | {:error, term()}


      


Sends a GET request. See request/3.

  



    

  
    
      
    
    
      patch(url, opts \\ [])



        
          
        

    

  


  

      

          @spec patch(String.t(), keyword()) :: {:ok, response()} | {:error, term()}


      


Sends a PATCH request. See request/3.

  



    

  
    
      
    
    
      post(url, opts \\ [])



        
          
        

    

  


  

      

          @spec post(String.t(), keyword()) :: {:ok, response()} | {:error, term()}


      


Sends a POST request. See request/3.

  



    

  
    
      
    
    
      put(url, opts \\ [])



        
          
        

    

  


  

      

          @spec put(String.t(), keyword()) :: {:ok, response()} | {:error, term()}


      


Sends a PUT request. See request/3.

  



    

  
    
      
    
    
      request(method, url, opts \\ [])



        
          
        

    

  


  

      

          @spec request(atom(), String.t(), keyword()) :: {:ok, response()} | {:error, term()}


      


Sends a method request to url and waits for the whole response.
Returns {:ok, response} whatever the status, and {:error, reason} when
there is no response, such as a Mint.TransportError.
Options
	:headers - a list of {name, value} headers
	:body - the body, as iodata
	:json - a term to send as JSON instead of a :body, with a
content-type of application/json unless one is given
	:timeout - how long to wait for the response, in milliseconds.
Defaults to 5_000.
	:metric - the timing to record the request as, or nil to record
nothing. Defaults to "http.request".
	:transport_opts - options for :gen_tcp or :ssl, given to
Mint.HTTP.connect/4


  


        

      


  

    
Stampede.LiveView 
    



      
A LiveView client for load tests.
{:ok, view} = Stampede.LiveView.connect("http://localhost:4000/counter")
{:ok, _reply} = Stampede.LiveView.click(view, "inc")
{:ok, _reply} = Stampede.LiveView.submit(view, "save", %{"user" => %{"name" => "jo"}})
{:ok, view} = Stampede.LiveView.navigate(view, "/posts")
connect/2 does what a browser does. It fetches the page over HTTP, reads
the CSRF token and the LiveView's signed session from it, opens the
LiveView socket with the cookies the page set, and joins the LiveView.
The connection is a Stampede.Channels socket, available as view.socket,
so it sends heartbeats and is closed at the end of an iteration like any
other. view.url is the URL of the LiveView the view is on.
Navigation
patch/3 and navigate/3 move between pages like <.link patch> and
<.link navigate> do, without loading the page again when LiveView would
not. When an event makes the LiveView navigate on its own, it returns
{:error, {:live_redirect, %{"to" => to}}}, or {:error, {:redirect, %{"to" => to}}} for a full redirect, as Phoenix.LiveViewTest does.
Follow either one with navigate/3.
Metrics
Inside a run, a view records:
	"live.page" and "live.page.errors" - fetching the page
	"live.join" and "live.join.errors" - joining the LiveView
	"live.event" and "live.event.errors" - events and their replies
	"live.patch" and "live.patch.errors" - patches
	"live.navigate" and "live.navigate.errors" - navigations over the
same socket. A navigation that needs a new page load records that
load instead.

along with the connection metrics listed in Stampede.Channels.

      


      
        Summary


  
    Types
  


    
      
        t()

      


    





  
    Functions
  


    
      
        await(view, timeout_or_opts \\ [])

      


        Waits for the LiveView to send an update of its own, such as one caused by
handle_info/2, and returns its diff.



    


    
      
        change(view, event, params, opts \\ [])

      


        Sends a form change, like a form with phx-change={event} would.



    


    
      
        click(view, event, value \\ %{}, opts \\ [])

      


        Sends a click, like an element with phx-click={event} would.



    


    
      
        close(view)

      


        Closes the connection.



    


    
      
        connect(url, opts \\ [])

      


        Fetches the page at url and connects to the LiveView it renders.



    


    
      
        navigate(view, to, opts \\ [])

      


        Navigates to the LiveView at to, like <.link navigate={to}> would.



    


    
      
        patch(view, to, opts \\ [])

      


        Patches the LiveView to to, like <.link patch={to}> would.



    


    
      
        submit(view, event, params, opts \\ [])

      


        Submits a form, like a form with phx-submit={event} would.



    





      


      
        Types


        


  
    
      
    
    
      t()



        
          
        

    

  


  

      

          @type t() :: %Stampede.LiveView{
  opts: term(),
  params: term(),
  root: term(),
  socket: Stampede.Channels.socket(),
  topic: String.t(),
  url: String.t()
}


      



  


        

      

      
        Functions


        


    

  
    
      
    
    
      await(view, timeout_or_opts \\ [])



        
          
        

    

  


  

      

          @spec await(t(), timeout() | keyword()) :: {:ok, map()} | {:error, term()}


      


Waits for the LiveView to send an update of its own, such as one caused by
handle_info/2, and returns its diff.
Takes a timeout in milliseconds, or the same options as
Stampede.Channels.await/4, with :match getting each diff.

  



    

  
    
      
    
    
      change(view, event, params, opts \\ [])



        
          
        

    

  


  

      

          @spec change(t(), String.t(), map(), keyword()) ::
  {:ok, map() | nil} | {:error, term()}


      


Sends a form change, like a form with phx-change={event} would.
params are the form's fields, nested the way handle_event/3 should
get them, such as %{"user" => %{"name" => "jo"}}. Takes the same
options and returns the same as click/4.

  



    

    

  
    
      
    
    
      click(view, event, value \\ %{}, opts \\ [])



        
          
        

    

  


  

      

          @spec click(t(), String.t(), map(), keyword()) ::
  {:ok, map() | nil} | {:error, term()}


      


Sends a click, like an element with phx-click={event} would.
value is what handle_event/3 gets as its params. Returns {:ok, reply}
once the LiveView has handled it, where reply is the map given to
{:reply, map, socket}, or nil when handle_event/3 returned
{:noreply, socket}. Returns {:error, :channel_crashed} if the LiveView
crashes while handling it.
Options
	:target - the component to send the event to, like phx-target
does. It is the number LiveView renders for phx-target={@myself};
components are numbered from 1, in the order they first render.
	:timeout - how long to wait for the reply, in milliseconds. Defaults
to 5_000.


  



  
    
      
    
    
      close(view)



        
          
        

    

  


  

      

          @spec close(t()) :: :ok


      


Closes the connection.

  



    

  
    
      
    
    
      connect(url, opts \\ [])



        
          
        

    

  


  

      

          @spec connect(String.t(), keyword()) :: {:ok, t()} | {:error, term()}


      


Fetches the page at url and connects to the LiveView it renders.
Options
	:headers - extra headers for both the page and the socket, such as a
cookie for pages behind a login
	:max_redirects - how many redirects to follow while loading the page,
keeping the cookies they set. Defaults to 5.
	:socket_path - where the LiveView socket is mounted. Defaults to
"/live".
	:timeout - how long to wait for each page request and for the join,
in milliseconds. Defaults to 5_000.
	:transport_opts - options for :gen_tcp or :ssl

Returns {:error, {:http_status, status}} when the page does not load or
redirects too many times, {:error, :no_live_view} when it has no
LiveView, and {:error, reply} when the LiveView refuses the join, for
example to redirect.

  



    

  
    
      
    
    
      navigate(view, to, opts \\ [])



        
          
        

    

  


  

      

          @spec navigate(t(), String.t(), keyword()) :: {:ok, t()} | {:error, term()}


      


Navigates to the LiveView at to, like <.link navigate={to}> would.
to is a path or a full URL. When the new LiveView is in the same
live_session, it joins over the same socket. Otherwise the page is
loaded again with connect/2, as a browser does. Returns {:ok, view}
for the new LiveView.
Takes a :timeout option, in milliseconds, that defaults to 5_000.

  



    

  
    
      
    
    
      patch(view, to, opts \\ [])



        
          
        

    

  


  

      

          @spec patch(t(), String.t(), keyword()) :: {:ok, t()} | {:error, term()}


      


Patches the LiveView to to, like <.link patch={to}> would.
to is a path, such as "/posts?page=2", or a full URL. The LiveView's
handle_params/3 runs, and {:ok, view} returns the view at its new URL.
When to belongs to another LiveView, it navigates there with
navigate/3 instead, as a browser does.
Takes a :timeout option, in milliseconds, that defaults to 5_000.

  



    

  
    
      
    
    
      submit(view, event, params, opts \\ [])



        
          
        

    

  


  

      

          @spec submit(t(), String.t(), map(), keyword()) ::
  {:ok, map() | nil} | {:error, term()}


      


Submits a form, like a form with phx-submit={event} would.
Takes the same arguments and returns the same as change/4.

  


        

      


  

    
Stampede.Reporter 
    



      
Formats a Stampede.Result for the terminal, or as JSON.

      


      
        Summary


  
    Functions
  


    
      
        format(result)

      


        Returns a summary of result, with a line per metric followed by the
checks, the thresholds and the most frequent errors, if there are any.



    


    
      
        to_json(result)

      


        Returns result as JSON, with every metric, the timeline, the thresholds
and the errors.



    





      


      
        Functions


        


  
    
      
    
    
      format(result)



        
          
        

    

  


  

      

          @spec format(Stampede.Result.t()) :: String.t()


      


Returns a summary of result, with a line per metric followed by the
checks, the thresholds and the most frequent errors, if there are any.

  



  
    
      
    
    
      to_json(result)



        
          
        

    

  


  

      

          @spec to_json(Stampede.Result.t()) :: String.t()


      


Returns result as JSON, with every metric, the timeline, the thresholds
and the errors.
Timings are in milliseconds and rates per second, as in Stampede.Result.

  


        

      


  

    
Stampede.Result 
    



      
The outcome of Stampede.run/2.
	:scenario - the scenario that ran
	:duration - how long it ran, in milliseconds
	:metrics - a map from each metric's name to its summary:	timings have type: :timing, :count, :rate, :min, :mean,
:p50, :p90, :p95, :p99 and :max, with times in milliseconds
	counters have type: :counter, :count and :rate
	checks have type: :check, :count, :rate, :passed, :failed
and :failed_rate, the share of checks that failed


	:timeline - one point per second of the run, each with the time it
ends at (:at, in milliseconds), the number of busy :vus, and the
:metrics of that second alone
	:thresholds - one map per limit, with :metric, :stat, :limit,
the :value it had and whether it :passed?
	:errors - the iterations that failed, grouped by kind of error, with a
:message and a :count, most frequent first
	:passed? - whether every threshold passed

Rates are per second.

      t()



        
          
        

    

  


  

      

          @type t() :: %Stampede.Result{
  duration: non_neg_integer(),
  errors: [%{message: String.t(), count: pos_integer()}],
  metrics: %{optional(String.t()) => map()},
  passed?: boolean(),
  scenario: module(),
  thresholds: [map()],
  timeline: [%{at: non_neg_integer(), vus: non_neg_integer(), metrics: map()}]
}


      



  


        

      


  

    
mix stampede.run 
    



      
Runs the load test scenarios defined in a file.
$ mix stampede.run loadtest/lobby.exs
$ mix stampede.run loadtest/lobby.exs --vus 100 --duration 1m
$ mix stampede.run loadtest/api.exs --rate 200 --duration 5m --out results.json

Every module in the file that implements Stampede.Scenario runs, one
after the other, with a progress line every second and a summary at the
end. The task exits with status 1 when a threshold fails, so it can gate CI.
Your project is compiled and configured, but its application is not
started, since the system under test usually runs somewhere else. Start
it in Stampede.Scenario.setup/1 if a scenario needs it.
Options
	--vus - how many VUs to run at once
	--rate - how many iterations to start per second, instead of --vus
	--duration - how long to run, such as 500ms, 30s, 5m or 1h
	--max-vus - how many iterations a --rate run may have in progress
	--out - a file to write the results to, as a JSON array with one
object per scenario, in the format of Stampede.Reporter.to_json/1
	--nodes - other nodes to run VUs on too, separated by commas

--vus and --rate replace the scenario's own VUs, rate and stages, and
--duration replaces its stages.
Running on several machines
Start a node on every machine, from the same project, and the task with
a name and the same cookie:
$ iex --sname worker --cookie load -S mix
$ elixir --sname loader --cookie load -S mix stampede.run loadtest/lobby.exs --nodes worker@host

The VUs are split evenly between the task's node and the given ones, and
the scenarios in the file are loaded on all of them.

